概要

Source code

//Simple CV Joint animated with OpenSCAD
//created by https://commons.wikimedia.org/wiki/User:MichaelFrey
//based on https://commons.wikimedia.org/wiki/File:Simple_CV_Joint_animated.gif
//by https://commons.wikimedia.org/wiki/User:Pwld

r1=25; //inner ball
r3=5;  //small balls

n=3; //grooves

r2=r1+r3;

r4=5; //Diameter for the rotary axes

h=80; //lenght of the axed

ang=-30; //angle betwhen the two axes

c =6; //cut off on the gear

convexity=20;
outershellOverhang = 5; //the finger needs to be longer
outershellClearance=3;

outershellThicknes=1;

$fn=120;

//--------------------

//rot = $t*360;
rot = $t*360/3;

color([1,0,0])
rotate([0,0,0])
rotate([rot,0,0]){
     outshell();
 }
 
 
 color([1,1,0])
 rotate([0,ang/2,0])
 rotate([rot,0,0]){
     balls();
 }
 
  color([0,1,0])
 rotate([0,ang,0])
 rotate([rot,0,0]){
    gear();
 }
module outshell(){
    for (i = [0 : 1 : n]){
        difference(){
            rotate([360/n*i])
            rotate_extrude(convexity = convexity)
            translate([r1,0,0])
            circle(r = r3+outershellThicknes);

            rotate([360/n*i])
            rotate_extrude(convexity = convexity)
                translate([r1,0,0])
                circle(r = r3);
            translate([r2+r3+2+outershellOverhang,0,0])
            cube(size =  (r2+2)*2 ,     center = true);
            
            sphere(r = r1+outershellClearance);
        }
    }
    
    translate([-r2-h/2, 0,0])
    rotate([90,90,90])
    cylinder(h=h, r=r4, center=true);
//}
}

 
 //balls
module balls(){
    for (i = [0 : 1 : n*2]){
        rotate([360/n*i/2])
        translate([0, r1,0])
        sphere(r = r3);
    }
 }
 
 module gear(){ //"gear" ball
    intersection(){
    difference(){
        rotate([0,90,0])
        sphere(r =r1);
        
         for (i = [0 : 1 : n]){
             rotate([360/n*i])
            rotate_extrude(convexity = convexity)
            translate([r1,0,0])
            circle(r = r3);
         }

     }
    cube(size =  [(r1-c)*2,(r1+2)*2,(r1+2)*2] ,     center = true);
    }
    translate([h/2, 0,0])
    rotate([90,90,90])
    cylinder(h=h, r=r4, center=true);
}

ライセンス

この作品の著作権者である私は、この作品を以下のライセンスで提供します。

このファイルはクリエイティブ・コモンズ 表示-継承 4.0 国際ライセンスのもとに利用を許諾されています。

あなたは以下の条件に従う場合に限り、自由に

• 共有 – 本作品を複製、頒布、展示、実演できます。
• 再構成 – 二次的著作物を作成できます。

あなたの従うべき条件は以下の通りです。

• 表示 – あなたは適切なクレジットを表示し、ライセンスへのリンクを提供し、変更があったらその旨を示さなければなりません。これらは合理的であればどのような方法で行っても構いませんが、許諾者があなたやあなたの利用行為を支持していると示唆するような方法は除きます。
• 継承 – もしあなたがこの作品をリミックスしたり、改変したり、加工した場合には、あなたはあなたの貢献部分を元の作品とこれと同一または互換性があるライセンスの下に頒布しなければなりません。

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue